COMMENT ⊗   VALID 00005 PAGES
C REC  PAGE   DESCRIPTION
C00001 00001
C00002 00002	% this file kludged together to make test figures for the METAFONTbook
C00004 00003	% U by Don Knuth
C00005 00004	% l by Don Knuth
C00006 00005	init.normal(1.618033*fudge)
C00007 ENDMK
C⊗;
% this file kludged together to make test figures for the METAFONTbook

if not known sss: sss=0; fi % sss is the amount of slant
if not known fudge: fudge=1; fi % fudge is the amount of resolution reduction
if known grayfont: special "grayfont "&grayfont; fi

input font1base
def showit=enddef;
def fill expr c = addto currentpicture contour c slanted sss enddef;

def makelabel(expr s)(text t) =
	forsuffixes $:=t:
	if known z$:
	special s&str$; numspecial x$+sss*y$; numspecial y$;
	fi endfor enddef;
def proofrule(expr a,b) =
	special "rule";
	numspecial xpart(a slanted sss); numspecial ypart(a slanted sss);
	numspecial xpart(b slanted sss); numspecial ypart(b slanted sss); enddef;

def autolabel = makelabel(" 6") enddef;

special "slantfont sl166"; % sss had better be 1/6 or 0
% U by Don Knuth
vardef char.U =
	setwidth .75em;
	pos1(1.1thickwidth,10);
	pos2(thickwidth,10);
	pos3(thickwidth,40);
	pos4(.5[thickwidth,thinwidth],75);
	pos5(.9[thickwidth,thinwidth],130);
	pos6(thinwidth,180);
	pos7(1.1thinwidth,190);
	x1l=.1em; x7l=w-.1em;
	y1=y7=capheight;
	x2=x1; y2=.3capheight; dz2=(0,-1);
	x3=.75[x4,x2]; y3=.75[y2,y4];
	x4r=.5[x2r,x6r]; y4l=-.05capheight; dz4=(1,0);
	x5=.71[x4,x6]; y5=.71[y6,y4];
	x6=x7; y6=1/3capheight; dz6=(0,1);
	stroke(1,2,.2,.05,.05);
	curve(2,3,4); curve(4,5,6);
	stroke(6,7,.8,.05,.05);
	labelpos(1,2,3,4,5,6,7);
enddef;
% l by Don Knuth
vardef char.l =
	setwidth 1/3em;
	pos1(1.5thickwidth,45);
	pos2(1.05thickwidth,10);
	z2=(.5w,0);
	y1=hheight; x1r=x2r;
	stroke(1,2,.1,.2,0);
	labelpos(1,2);
enddef;
init.normal(1.618033*fudge);
proofing:=1;

vardef make@#=begingroup clear; charcode:=ord str@#;
 "the character "&str @#; char@#; shipit;
endgroup enddef;

make.U;
make.l;
end